Come usare la funzione RICERCA in Microsoft Excel

Scansionare i fogli Excel a mano è una ricetta per un mal di testa. Che tu stia evidenziando parole chiave o convalidando ID, la funzione CERCA è il tuo miglior strumento per "leggere" il testo all'interno di una cella. Ecco come padroneggiare la sintassi e quattro utilizzi pratici.

Come funziona la funzione CERCA in Excel

Padroneggia la sintassi per trovare qualsiasi stringa di testo

La funzione CERCA trova un carattere o una parola e restituisce la sua posizione iniziale.

La sintassi

La funzione RICERCA ha tre argomenti:

=SEARCH(find_text, within_text, [start_num])

dove :

• find_text (obbligatorio) è il testo che vuoi individuare (tra virgolette). Se Excel non riesce a trovare il testo, SEARCH restituisce l'errore #VALUE!.
• within_text (obbligatorio) è la stringa di testo da cercare (tipicamente una cella).
• start_num (facoltativo) indica a Excel da dove iniziare a cercare all'interno della stringa di testo. Se lo lasci vuoto, Excel inizia dal primo carattere. Assicurati solo che questo valore non sia maggiore della lunghezza del testo per evitare l'errore #VALUE!.

Il vantaggio di SEARCH: Perché non usare funzioni più recenti, Power Query o Python?

Mentre gli strumenti moderni di Excel possono spesso fare lo stesso lavoro, SEARCH è ancora una scelta abituale per molte attività quotidiane. Ecco perché:

• Immediatezza: SEARCH è una formula "live". Si aggiorna nel momento in cui termini di digitare, mentre altri strumenti potrebbero richiedere aggiornamenti o impiegare più tempo per eseguire l'operazione.
• Compatibilità: Funzioni più recenti come REGEXTEST o TEXTBEFORE non funzioneranno se condividi il tuo file con qualcuno che utilizza una versione precedente di Excel. SEARCH funziona in quasi tutte le versioni di Excel.
• Nessuna configurazione: Non è necessario imparare un secondo linguaggio di programmazione o creare query separate. Tutto avviene direttamente all'interno delle tue celle utilizzando un flusso di lavoro che già conosci.

Caso d'uso 1: Creazione di un flag logico "contiene"

Trasforma testo disordinato in risultati semplici VERO o FALSO

Da solo, un numero di posizione come "5" non è sempre utile per un rapporto finale. Tuttavia, racchiudere SEARCH in ISNUMBER crea un potente test di "contiene" che verifica semplicemente se la parola chiave esiste.

Lo scenario: Nella colonna Status della tua tabella T_Transactions, vuoi etichettare qualsiasi transazione contenente la parola "Refund" come "Azione Richiesta." Tutte le altre transazioni dovrebbero essere etichettate come "Approvate."

Nella cella D2, digita quanto segue e premi Invio:

=IF(ISNUMBER(SEARCH("Refund", [@Description])), "Action Required", "Cleared")

Ecco come funziona questa formula:

• SEARCH("Refund", [@Description]): Questo cerca la parola "Refund" nella riga corrente della colonna Description. Se trovata, restituisce un numero. Altrimenti, restituisce un errore.
• ISNUMBER(...): Questo verifica il risultato della ricerca. Se rileva un numero, restituisce VERO. Se rileva un errore, restituisce FALSO.
• SE(...,"Azione Richiesta","Autorizzato"): Questo è il passaggio finale. Se il passaggio precedente ha restituito VERO, mostra "Azione Richiesta." Se ha restituito FALSO, mostra "Autorizzato."

Caso d'uso 2: Padroneggiare le corrispondenze parziali con i caratteri jolly

Usa asterischi e punti interrogativi per il matching dei modelli

A volte l'immissione dei dati non è perfettamente standardizzata. Potresti avere un ID specifico all'inizio di un numero di serie, ma nascosto nel mezzo di un altro. Usando un asterisco, puoi colmare il divario tra due informazioni conosciute, indipendentemente da quanti caratteri ci siano tra di esse.

Lo scenario: Nella tua tabella T_ProductCodes, devi identificare ogni prodotto della serie "TS" che appartiene al lotto di produzione "2026", anche se sono separati da diversi codici città o numeri di lotto.

Questo è ciò che dovrai digitare nella cella D2:

=ISNUMBER(SEARCH("TS*2026", [@SerialNumber]))

Scomponiamo la formula:

• "TS*2026": L'asterisco è un carattere jolly che rappresenta un numero qualsiasi di caratteri. Questo indica a Excel di trovare "TS," poi saltare qualsiasi quantità di testo fino a incontrare "2026."
• SEARCH(...): Questo cerca quel modello specifico all'interno della colonna SerialNumber. Non importa se lo spazio è di due caratteri o di 20—se entrambe le stringhe appaiono in quell'ordine, la ricerca restituisce un numero.
• ISNUMBER(...): Questo converte la posizione numerica in VERO o FALSO.

Caso d'uso 3: Utilizzo della formattazione condizionale dinamica

Fai reagire visivamente le righe del tuo foglio di calcolo ai tuoi dati

Puoi usare SEARCH per cambiare il colore di un'intera riga ogni volta che appare una parola chiave specifica.

Scenario: Vuoi che qualsiasi riga nella tua tabella T_ProjectTracker in cui il nome del cliente contenga "Acme" diventi di colore azzurro chiaro.

Ecco i passaggi:

1. Seleziona la tua tabella (escludendo la riga dell'intestazione).
2. Vai a Home > Formattazione condizionale > Nuova regola.
3. Fai clic su Usa una formula per determinare quali celle formattare.
4. Clicca su Formato, imposta il tuo colore di riempimento su azzurro chiaro.
5. Inserisci la seguente formula nel campo vuoto (assicurandoti che il numero della riga corrisponda alla prima riga della tua selezione) e fai clic su OK:

=ISNUMBER(SEARCH("Acme", $B2))

Ecco cosa sta succedendo questa volta:

• $B2: Il simbolo del dollaro "blocca" la ricerca alla colonna B (Nome Cliente).
• SEARCH("Acme",...): Questo cerca nel nome del cliente la stringa di testo "Acme." Ricorda, SEARCH non distingue tra maiuscole e minuscole.
• ISNUMBER(...): Se viene trovato "Acme", SEARCH restituisce un numero, ISNUMBER restituisce VERO e l'evidenziazione blu viene applicata all'intera riga.

Caso d'uso 4: Validazione dei dati con logica posizionale

Individua le coordinate esatte dei personaggi per regole complesse.

Gli utenti esperti spesso usano CERCA come un metro. Poiché la funzione restituisce una coordinata numerica (la posizione del carattere), è possibile attivare azioni solo quando un carattere appare in un punto specifico di una cella.

Lo scenario: Devi categorizzare i codici nella colonna DepartmentCode della tua tabella T_EmployeeData: i codici "Legacy" devono contenere un trattino nei primi cinque caratteri, mentre qualsiasi codice in cui il trattino appare più tardi è classificato come "Standard."

Ecco la formula di cui avrai bisogno:

=IF(SEARCH("-", [@DepartmentCode]) <= 5, "Legacy", "Standard")

Ecco come funziona:

• SEARCH("-", [@DepartmentCode]): Invece di verificare semplicemente se il trattino è presente, questo individua la sua posizione esatta.
• <= 5: Questo chiede, "La posizione del trattino è minore o uguale a 5?"
• SE(..., "Legacy", "Standard"): Se il trattino viene trovato nella posizione 5 o precedente, il test è VERO e la riga è etichettata come "Legacy." Altrimenti, otteniamo "Standard."

La bellezza della funzione CERCA è che trasforma un foglio di calcolo statico in uno strumento reattivo che rileva gli errori prima di te. Ora, per portare ancora più avanti le tue abilità di pulizia, padroneggia la funzione Vai a speciale: è il modo ideale per individuare formule nascoste o celle vuote che CERCA potrebbe non rilevare.